home *** CD-ROM | disk | FTP | other *** search
/ ETO Development Tools 4 / ETO Development Tools 4.iso / Tools - Objects / Virtual User 1.0 / Example Scripts / SimpleSample.vu < prev    next >
Text File  |  1991-01-25  |  4KB  |  126 lines
  1. #
  2. #    File SimpleSample.vu 
  3. #
  4. #    Contains:    A script which creates a folder with 3 sub-folders and does
  5. #                some simple user actions at a slow pace for you to observe.
  6. #                Note that all lines starting with a '#' is a comment 
  7. #                (like this one).                 
  8. #                
  9. #
  10. #    Starting Configuration:    In order for the script to run properly, the target
  11. #                should be running Finder with all windows closed and one disk
  12. #                icon selected. The target Macintosh should have a Printer
  13. #                software installed. If you have access to a printer then use
  14. #                the Chooser to select one.
  15. #
  16. #    After Effects: This script creates a folder called "..VUSimpleSample.." in 
  17. #                the volume selected initially. Please throw it in the trash
  18. #                after you execute this script once.
  19. #
  20. #    Note:        To stop the script execution while its running type Cmd-.
  21. #                ie., Press the Command Key and type '.' (period).
  22. #
  23. #    Written by:    Rick Violet
  24. #
  25. #    Copyright:    © 1990 by Apple Computer, Inc., all rights reserved.
  26. #
  27. #    Change History:
  28. #
  29. #         1/21/90        Rick        Created first draft
  30. #         1/24/90        naga        Edited the script and comments
  31. #
  32.  
  33. ################################################################################
  34. ########                Create a new folder window
  35. ################################################################################
  36. #Tell VU to slow its movements for Demonstration purpose
  37. Patience(2);
  38. MouseSpeed(10);
  39.  
  40. #    Open the root window of the selected volume, by selecting "Open" from the
  41. #    file menu.
  42. Select [ menuitem t:"Open" ];
  43.  
  44. #    Unify the window's name into a variable (Volume_Name) for later use.
  45. match[ window o:1 t:?Volume_Name ];
  46.  
  47. #    Initialize a variable for our folder's name.
  48. Our_Window_Name := "..VUSimpleSample..";
  49.  
  50. #    Create a new folder by selecting 'New', using the key equivalent.
  51. pressKey    k:{ commandKey };
  52. type        k:{"n"};
  53. releaseKey    k:{ commandKey };
  54.  
  55. #    We can rename the folder by simply typing.
  56. Type k:{ Our_Window_Name };
  57.  
  58. #    Open the new folder's window by selecting "Open" from the file menu.
  59. Select [ menuitem t:"Open" ];
  60.  
  61. #    Check for 'Name already taken' dialog
  62. if match[ button t:"Ok" w:0 ]
  63.     begin
  64.         println "Target not setup to run this script";
  65.         println "Please trash the '{Our_Window_Name}' folder.";
  66.         exit;
  67.     end;
  68.     
  69. #    Select and then Close the root window. 
  70. #    the variable Volume_Name contains the window's title.
  71. Select[ window t:Volume_Name ];
  72. Close[ window t:Volume_Name ];
  73.  
  74. #    Create 3 new folders in this folder using Command-n
  75. pressKey    k:{ commandKey };
  76. type        k:{"nnn"};
  77. releaseKey    k:{ commandKey };
  78.  
  79.  
  80. #    Resize the window to be thin and as tall as the screen.
  81. #    First find the rectangle of the main screen
  82. match[ screen main:true r:?Main_Screen_Rect];
  83.         
  84. #    Drag the window to the top-left corner of the screen
  85. Drag [ window o:1 ] a:{ Main_Screen_Rect[1],
  86.                         Main_Screen_Rect[2] + 20 }; # bump down 20 for Menubar
  87.  
  88. #    Now resize the window.
  89. Size [ window o:1 ] w:180  h:(Main_Screen_Rect[4] - Main_Screen_Rect[2] - 20 );
  90.  
  91. #    View the window by small icon.
  92. Select[ menuitem t:"by Small Icon" m:"View" ];
  93.  
  94. #    Force Finder to clean up the window
  95. pressKey    k:{ optionKey };
  96. Select[ menuitem t:"Clean up" ];
  97. releaseKey    k:{ optionKey };
  98.  
  99. #    Zoom the window out 
  100. Zoom [ window o:1 ];
  101.  
  102. #    Do Page setup
  103. Select[ menuitem t:"Page Setup…" m:"File"];
  104.  
  105. # If Page setup dialog comes up.
  106. if match [ radioButton t:"US letter" w:1 ]
  107. begin
  108.     Select [ radioButton t:"US letter" w:1 ];# Select a radio button, "US letter"
  109.  
  110.     # Check any check boxes that are currently un-checked in the front window
  111.     # First, collect the list of all un-checked boxes in the front window
  112.     All_Marked_CheckBoxes := Collect[ checkbox s:{0,1} w:1 ]!;    
  113.     For each CB in All_Marked_CheckBoxes        #    For each one in the list
  114.         Select [checkBox t:CB.t r:CB.r w:1];    #    check the box
  115. end;#if Page setup dialog comes back
  116.  
  117. Select[ button t:'Ok' w:1];                        #     dissmiss dialog
  118.  
  119. # Close the window titled '..VUSimpleSample..'
  120. Close [window t: Our_Window_Name];
  121.  
  122. # Open the root volume window
  123. Select [menuItem t:'Open' m:'File'];
  124.  
  125. println "Please, don't forget to trash the '{Our_Window_Name}'∂n",
  126.         "folder on your target Macintosh";